assume cs:code
stack segment
dw 128 dup (0)
stack ends
code segment
start:
mov ax,stack
mov ss,ax
mov sp,128
push cs
pop ds
mov ax,0
mov es,ax
mov si,offset setscreen
mov di,204h
mov cx,offset setscreenend-offset setscreen
cld
rep movsb
push es:[9*4]
pop es:[200h]
push es:[9*4+2]
pop es:[202h]
cli
mov word ptr es:[9*4],204h
mov word ptr es:[9*4+2],0
sti
mov ax,0b800h
mov es,ax
mov byte ptr es:[160*8+50],35h
s1:
mov cx,0
loop s1
mov ax,4c00h
int 21h
setscreen:
push ax
push bx
push cx
push es
in al,60h
pushf
call dword ptr cs:[200h];调用原来的int9中断
cmp al,0bh;//判断方法1
ja set
cmp al,2;扫描到的按键值大于b或小于2都跳到set
jb set
table0 db 0,1,2,3;对应0，1，2，3
table1 db 0bh,2,3,4;0，1，2，3的案件通码
push bx
mov bx,0
s9:cmp al,table1[bx]
je s8
inc bx
jmp s9
s8:
mov al,table0[bx]
pop bx ;//判断方法1
;cmp al,0bh;//判断方法2
;ja set
;cmp al,2;扫描到的按键值大于b或小于2都跳到set
;jb set
;cmp al,0bh
;je e0
;jb e1
;e0:mov al,0
;jmp short e2;当判断出是‘0’按键时跳过dec al，跳到e2
;e1:dec al;当判断出是'1,2,3'按键时自动减1使al值对应按键值
;//判断方法2
e2:mov ah,al
mov al,2
jmp far ptr set
table dw sub1,sub2,sub3,sub4
sub1:push bx;清屏
push cx
push es
mov bx,0b800h
mov es,bx
mov bx,0
mov cx,2000
sub1s:mov byte ptr es:[bx],' '
add bx,2
loop sub1s
pop es
pop cx
pop bx
ret
sub2:push bx;设置前景颜色
push cx
push es
mov bx,0b800h
mov es,bx
mov bx,1
mov cx,2000
sub2s:and byte ptr es:[bx],11111000b
or es:[bx],al
add bx,2
loop sub2s
pop es
pop cx
pop bx
ret
sub3:push bx;设置背景颜色
push cx
push es
mov cl,4
shl al,cl
mov bx,0b800h
mov es,bx
mov bx,1
mov cx,2000
sub3s:and byte ptr es:[bx],10001111b
or es:[bx],al
add bx,2
loop sub3s
pop es
pop cx
pop bx
ret
sub4:push cx;向上滚一行
push si
push di
push es
push ds
mov si,0b800h
mov es,si
mov ds,si
mov si,160
mov di,0
cld
mov cx,24
sub4s:push cx
mov cx,160
rep movsb
pop cx
loop sub4s
mov cx,80
mov si,0
sub4s1:mov byte ptr [160*24+si],' '
add si,2
loop sub4s1
pop ds
pop es
pop di
pop si
pop cx
ret
set:push bx
cmp ah,3
ja sret
mov bl,ah
mov bh,0
add bx,bx;选择程序
call word ptr table[bx]
sret:pop bx
pop es
pop cx
pop bx
pop ax
iret
setscreenend:nop
code ends
end start
这个程序要实现的功能是运行程序后，按0键 清屏，按1键设置前景色为绿色，按2键设置背景色为绿色，按3键向上滚动一行。
红色的部分为第2个方法，可以实现功能。紫色的部分为第1个方法，第1个方法无法实现：按0~9都清屏，这是怎么回事呢？table0 db 0,1,2,3 table1 db 0bh,2,3,4这是不是没起作用呢？table1[bx]和table0[bx]用的对吗？
请大家帮我看看，谢谢
------解决思路----------------------
1. jb set 指令后就定义 table0/1 数据，这个会有问题。如果 jb 不跳转，就会将 table0/1 定义的数据当做指令执行了，后果难料。数据通常分开在单独的区块进行定义，间杂在代码里也要保证不被执行到，比如在 jmp 指令后，或用 jmp 指令跳过。
2. 虽然定义了 table0/1，但直接使用它们在你这里是错误的，因为在你代码里，和这部分代码最后执行时的起始偏址是不一样的，就会造成引用了错误的地址。比较简单的做法就是在 setscreen: 前加上 org 204h 语句，因为这部分代码是要被挪移到 0000:0204 处执行的。