package
{
import flash.display.Sprite;
/**
* 排序测试类
* 排序算法的分类如下：
* 1.插入排序（直接插入排序、折半插入排序、希尔排序）；
* 2.交换排序（冒泡泡排序、快速排序）；
* 3.选择排序（直接选择排序、堆排序）；
* 4.归并排序；
* 5.基数排序。
* 关于排序方法的选择：
* (1)若n较小(如n≤50)，可采用直接插入或直接选择排序。
* 当记录规模较小时，直接插入排序较好；否则因为直接选择移动的记录数少于直接插人，应选直接选择排序为宜。
* (2)若文件初始状态基本有序(指正序)，则应选用直接插人、冒泡或随机的快速排序为宜；
* (3)若n较大，则应采用时间复杂度为O(nlgn)的排序方法：快速排序、堆排序或归并排序。
*/
public class SortTest extends Sprite
{
public function SortTest()
{
super();
//test
}
/**
* 创建一个随机数组
* @return
*
*/
private function createArray():Array
{
var array:Array = [];
for(var i:int = 0;i<10;i++)
{
array[i] = int(Math.random()*100) - int(Math.random()*100);//生成两个随机数相减，保证生成的数中有负数
}
return array;
}
/**
* 冒泡排序----交换排序的一种
* 方法：相邻两元素进行比较，如有需要则进行交换，每完成一次循环就将最大元素排在最后（如从小到大排序），下一次循环是将其他的数进行类似操作。
* 性能：比较次数O(n^2),n^2/2；交换次数O(n^2),n^2/4
* @param arr 要排序的数组
* @param sortType 排序类型
*
*/
private function bubbleSort(data:Array,sortType:String):void
{
if (sortType == "asc")
{ // 正排序，从小排到大
// 比较的轮数
for (var i:int = 1;i < data.length;i++)
{
// 将相邻两个数进行比较，较大的数往后冒泡
for (var j:int = 0; j < data.length - i; j++)
{
if (data[j] > data[j + 1])
{
// 交换相邻两个数
swap(data, j, j + 1);
}
}
}
}else if (sortType == "desc")
{ // 倒排序，从大排到小
// 比较的轮数
for (var a:int = 1;a < data.length;a++)
{
// 将相邻两个数进行比较，较大的数往后冒泡
for (var k:int = 0; k < data.length - a; k++)
{
if (data[k] < data[k + 1]) {
// 交换相邻两个数
swap(data, k, k + 1);
}
}
}
} else
{
trace("您输入的排序类型错误！");
}
trace(data);
}
/**
* 直接选择排序法----选择排序的一种
* 方法：每一趟从待排序的数据元素中选出最小（或最大）的一个元素， 顺序放在已排好序的数列的最后，直到全部待排序的数据元素排完。
* 性能：比较次数O(n^2),n^2/2
* 交换次数O(n),n
* 交换次数比冒泡排序少多了，由于交换所需CPU时间比比较所需的CUP时间多，所以选择排序比冒泡排序快。
* 但是N比较大时，比较所需的CPU时间占主要地位，所以这时的性能和冒泡排序差不太多，但毫无疑问肯定要快些。
* @param data 要排序的数组
* @param sortType 排序类型
*
*/
private function selectSort(data:Array,sortType:String):void
{
if (sortType == "asc")
{ // 正排序，从小排到大
var index0:int;
for (var i:int = 1; i < data.length; i++)
{
index0 = 0;
for (var j:int = 1; j <= data.length - i; j++)
{
if (data[j] > data[index0])
{
index0 = j;
}
}
// 交换在位置data.length-i和index0(最大值)两个数
swap(data, data.length - i, index0);
}
}else if (sortType == "desc")
{ // 倒排序，从大排到小
var index1:int;
for (var a:int = 1; a < data.length; a++)
{
index1 = 0;
for (var b:int = 1; b <= data.length - a;b++)
{
if (data[b] < data[index1])
{
index1 = b;
}
}
// 交换在位置data.length-i和index(最大值)两个数
swap(data, data.length - a, index1);
}
}else
{
trace("您输入的排序类型错误！");
}
trace(data);
}
/**
* 插入排序
* 方法：将一个记录插入到已排好序的有序表（有可能是空表）中,从而得到一个新的记录数增1的有序表。
* 性能：比较次数O(n^2),n^2/4
* 复制次数O(n),n^2/4
* 比较次数是前两者的一般，而复制所需的CPU时间较交换少，所以性能上比冒泡排序提高一倍多，而比选择排序也要快。
* @param data 要排序的数组
* @param sortType 排序类型
*
*/
private function insertSort(data:Array,sortType:String):void
{
if (sortType == "asc")
{ // 正排序，从小排到大
// 比较的轮数
for (var i:int = 1; i < data.length; i++)
{
// 保证前i+1个数排好序
var temp0:int = data[i];
var j:int;
for (j = i; j > 0 && data[j - 1] < temp0; j--)
{
data[j] = data[j - 1];
}
data[j] = temp0;
}
} else if (sortType == "desc")
{ // 倒排序，从大排到小
// 比较的轮数
for (var a:int = 1; a < data.length; a++)
{
// 保证前a+1个数排好序
var temp1:int = data[a];
var b:int;
for (b = a; b > 0 && data[b - 1] < temp1; b--)
{
data[b] = data[b - 1];
}
data[b] = temp1;
}
} else
{
trace("您输入的排序类型错误！");
}
trace(data);
}
/**
* 快速排序
* 快速排序使用分治法（Divide and conquer）策略来把一个序列（list）分为两个子序列（sub-lists）。
* 步骤为:
* 1. 从数列中挑出一个元素，称为 "基准"（pivot),
* 2. 重新排序数列，所有元素比基准值小的摆放在基准前面，所有元素比基准值大的摆在基准的后面（相同的数可以到任一边）。在这个分割之后，该基准是它的最后位置。这个称为分割（partition）操作。
* 3. 递归地（recursive）把小于基准值元素的子数列和大于基准值元素的子数列排序。
* 递回的最底部情形，是数列的大小是零或一，也就是永远都已经被排序好了。虽然一直递回下去，但是这个算法总会结束，因为在每次的迭代（iteration）中，它至少会把一个元素摆到它最后的位置去。
* @param data 待排序的数组
* @param sortType
*
*/
private function quickSort(data:Array,sortType:String):void
{
if (sortType == "asc")
{ // 正排序，从小排到大
qsort_asc(data, 0, data.length - 1);
} else if(sortType =="desc")
{ // 倒排序，从大排到小
qsort_desc(data, 0, data.length - 1);
} else {
trace("您输入的排序类型错误！");
}
trace(data);
}
/**
* 快速排序的具体实现，排正序
* @param data
* @param low
* @param high
*
*/
private function qsort_asc(data:Array,low:int,high:int):void
{
var i:int;
var j:int;
var x:int;
if (low < high)
{ // 这个条件用来结束递归
i = low;
j = high;
x = data[i];
while (i < j)
{
while (i < j && data[j] > x)
{
j--; // 从右向左找第一个小于x的数
}
if (i < j)
{
data[i] = data[j];
i++;
}
while (i < j && data[i] < x)
{
i++; // 从左向右找第一个大于x的数
}
if (i < j)
{
data[j] = data[i];
j--;
}
}
data[i] = x;
qsort_asc(data, low, i - 1);
qsort_asc(data, i + 1, high);
}
}
/**
* 快速排序的具体实现，排倒序
* @param data
* @param low
* @param high
*
*/
private function qsort_desc(data:Array,low:int,high:int):void
{
var i:int;
var j:int;
var x:int;
if (low < high)
{ // 这个条件用来结束递归
i = low;
j = high;
x = data[i];
while (i < j)
{
while (i < j && data[j] < x)
{
j--; // 从右向左找第一个小于x的数
}
if (i < j)
{
data[i] = data[j];
i++;
}
while (i < j && data[i] > x)
{
i++; // 从左向右找第一个大于x的数
}
if (i < j)
{
data[j] = data[i];
j--;
}
}
data[i] = x;
qsort_desc(data, low, i - 1);
qsort_desc(data, i + 1, high);
}
}
/**
* 二分查找特定整数在整型数组中的位置(递归)
* 查找线性表必须是有序列表
* @param dataset
* @param data
* @param beginIndex
* @param endIndex
*
*/
public function binarySearch_0(dataset:Array,data:int,beginIndex:int,endIndex:int):int
{
var midIndex:int = (beginIndex + endIndex)/2;
if (data < dataset[beginIndex] || data > dataset[endIndex]
|| beginIndex > endIndex)
return -1;
if (data < dataset[midIndex])
{
return binarySearch_0(dataset, data, beginIndex, midIndex - 1);
} else if (data > dataset[midIndex])
{
return binarySearch_0(dataset, data, midIndex + 1, endIndex);
} else {
return midIndex;
}
}
/**
* 二分查找特定整数在整型数组中的位置(非递归)
* 查找线性表必须是有序列表
* @param dataset
* @param data
*
*/
public function binarySearch_1(dataset:Array,data:int):int
{
var beginIndex:int = 0;
var endIndex:int = dataset.length - 1;
var midIndex:int = -1;
if (data < dataset[beginIndex] || data > dataset[endIndex]
|| beginIndex > endIndex)
return -1;
while (beginIndex <= endIndex)
{
midIndex = (beginIndex + endIndex)/2;
if (data < dataset[midIndex])
{
endIndex = midIndex - 1;
} else if (data > dataset[midIndex])
{
beginIndex = midIndex + 1;
} else
{
return midIndex;
}
}
return -1;
}
/**
* 反转数组的方法
* @param data 数组源
*
*/
private function reverse(data:Array):void
{
var length:int = data.length;
var temp:int = 0;
for (var i:int = 0; i < length / 2; i++)
{
temp = data[i];
data[i] = data[length - 1 - i];
data[length - 1 - i] = temp;
}
}
/**
* 交换数组中指定的两元素的位置
* @param arr
* @param x
* @param y
*
*/
private function swap(arr:Array,x:int,y:int):void
{
var temp:int = arr[x];
arr[x] = arr[y];
arr[y] = temp;
}
}
}